Procedure Send Mail Alert - stored-procedures

Question

I have a procedure which sends emails and this procedure is being called from other functions and procedures (primarily used for sending alerts and notifications).
One issue I face is if our mail server is down, then calling function or procedure stops execution, I mean they do not do any functionality which they are supposed to do. How can I make sure that calling function or procedure or for that matter any client which calls
MailProcedure should do its functionality even when mail server is down.
How can I achieve this?
Any help is highly appreciable.
Mail Procedure
CREATE OR REPLACE PROCEDURE MailProcedure(frm_id IN VARCHAR2, to_id IN VARCHAR2, subject IN VARCHAR2, body_text IN VARCHAR2)
AS
c utl_tcp.connection;
rc integer;
BEGIN
c := utl_tcp.open_connection('email_server', 25);
rc := utl_tcp.write_line(c, 'string');
rc := utl_tcp.write_line(c, 'from address');
rc := utl_tcp.write_line(c, 'to address');
rc := utl_tcp.write_line(c, 'Subject');
rc := utl_tcp.write_line(c, 'body');
utl_tcp.close_connection(c);
EXCEPTION
WHEN OTHERS
THEN
null;
END;
/

Answer 1

Since you want to queue the email for later delivery, the simplest option is to send all email messages asynchronously. Your other procedures would call a QueueMail procedure that inserts a row into the new mail_queue table
CREATE OR REPLACE PROCEDURE QueueMail(p_from IN VARCHAR2,
p_to IN VARCHAR2,
p_subject IN VARCHAR2,
p_body IN VARCHAR2)
AS
BEGIN
INSERT INTO mail_queue( mail_queue_id. from, to, subject, body )
VALUES( mail_queue_seq.nextval, p_from, p_to, p_subject, p_body );
END;
You would then have a separate procedure that runs in a separate thread that actually sense the emails and removes the messages from the queue. Something like
CREATE OR REPLACE PROCEDURE SendQueuedMessages
AS
BEGIN
FOR msg IN (SELECT * FROM mail_queue )
LOOP
sendMessage( msg.from, msg.to, msg.subject, msg.body );
DELETE FROM mail_queue
WHERE mail_queue_id = msg.mail_queue_id;
commit;
END LOOP;
END;
where sendMessage implements the actual logic for sending an email. I would think that you would want to use either the utl_mail or the utl_smtp package to send email rather than using utl_tcp but, of course, you can use utl_tcp. You would then schedule the SendQueuedMessages procedure using either the dbms_job or the dbms_scheduler package. Something like this
DECLARE
l_jobno PLS_INTEGER;
BEGIN
dbms_job.submit( l_jobno,
'BEGIN SendQueuedMessages; END;',
sysdate + interval '1' minute,
'sysdate + interval ''1'' minute' );
commit;
END;
will create a job that runs the SendQueuedMessages procedure every minute. If the mail server is down, the SendQueuedMessage procedure fails and the job is automatically rescheduled to run later. After the first failure, the job runs again 1 minute later. After the second failure, it runs 2 minutes later, then 4 minutes, 8 minutes, etc. until it fails 16 consecutive times. You can choose something other than the default behavior if you want to catch the exceptions in the SendQueuedMessages procedure. Since job failures cause the failure to be written to the alert log, your DBA may ask you to handle the exceptions and to handle rescheduling the job to avoid unnecessary data being written to the alert log.