INDY command handler. Success response with a parameter - delphi

Question

I followed the demo and things are working just fine. My client has a single function to send commands to the server and handle the response.
That was fine for the first few command and I handle it by
var result : String;
TCPclient.SendCmd(theMessage);
TCPclient.GetResponse(Result);
if Result <> 'OK' then ....
Where the server is sending
ASender.Reply.SetReply(200, 'OK'); ... or ...
ASender.Reply.SetReply(400, 'NAK');
Now, I want to add a new command and the result will be either NAK or ACK PLUS a value 0, 1 or 2
I am hazy on response codes which seem to have two parameters, one numerical and one textual ....
I could just kludge and send 'Ok0', 'OK1', or 'OK2', but that is very ugly (and probably A Bad Thing)
I think I though to use 200 for success and send 0, 1 or 2 in the textual parameter (or use 'OK' and send 0, 1 or 2 as numeric code, or use 200, 201, 202 as numeral code)?
Can someone please help me understand what I ought to be coding and why? (Or just point me at a URL) Thanks

Answer 1

SendCmd() reads the response from the server for you, so DO NOT call GetResponse() after SendCmd() unless the server actually sends two separate responses.
Responses typically take the form:
<Response Code> <Optional Text>
Where the response code is either a number or a textual keyword.
If the server sends numeric response codes, handle it like this:
Server:
// sends:
//
// 200 1
//
ASender.Reply.SetReply(200, '1');
Client:
if TCPclient.SendCmd(theMessage) = 200 then
Value := StrToInt(TCPclient.LastCmdResult.Text.Text);
Or:
// raises an exception if a non-200 response is received
TCPclient.SendCmd(theMessage, 200);
Value := StrToInt(TCPclient.LastCmdResult.Text.Text);
If the server sends textual response codes, handle it like this:
Server:
// sends:
//
// OK 1
//
ASender.Reply.SetReply('OK', '1');
Client:
if TCPclient.SendCmd(theMessage, '') = 'OK' then
Value := StrToInt(TCPclient.LastCmdResult.Text.Text);
Or:
// raises an exception if a non-OK response is received
TCPclient.SendCmd(theMessage, ['OK']);
Value := StrToInt(TCPclient.LastCmdResult.Text.Text);
The optional text of the response, if present, can be accessed in the TCPclient.LastCmdResult.Text property, which is a TStrings as it is possible to send multi-line responses in the form:
<Response Code>-<Optional Text>
<Response Code>-<Optional Text>
...
<Response Code> <Optional Text>
Server:
// sends:
//
// 200-The value is
// 200 1
//
ASender.Reply.SetReply(200, 'The value is');
ASender.Reply.Text.Add('1');
Client:
TCPclient.SendCmd(theMessage, 200);
Value := StrToInt(TCPclient.LastCmdResult.Text[1]);
You can also send secondary multi-line text after the responses in this form:
<Response Code> <Optional Text>
<Secondary Text>
.
Server:
// sends:
//
// 200 Data follows
// Hello world
// How are you?
// .
//
ASender.Reply.SetReply(200, 'Data follows');
ASender.Reply.Response.Add('Hello world');
ASender.Reply.Response.Add('How are you?');
Client:
TCPclient.SendCmd(theMessage, 200);
TCPclient.IOHandler.Capture(SomeTStringsObj);