Grails JMS Plugin to WebLogic JMS Server - grails

Question

Has anyone configured Grails 2.x JMS Plugin to send/receive messages to a remote WebLogic JMS Server? I've tried resources.groovy configurations like this with no luck:
jmsConnectionFactory(InitialContext, [
"INITIAL_CONTEXT_FACTORY": "weblogic.jndi.WLInitialContextFactory",
"PROVIDER_URL": "t3://remote-host:7001",
"SECURITY_PRINCIPAL": "weblogic",
"SECURITY_CREDENTIALS": "weblogic"])

Answer 1

Not much resources with complete answers are on net about sending/receiving JMS in Grails with remote Weblogic server, so I figured out 2-3 years ago a working solution, without need of any plugins.
Make sure that at least Weblogic wlthint3client.jar is in lib directory.
Setting up JMS listener:
in conf/spring/resources.groovy:
// Weblogic's JMS setup on Grails
jndiTemplate(org.springframework.jndi.JndiTemplate) {
environment = [
"java.naming.factory.initial" : "weblogic.jndi.WLInitialContextFactory",
"java.naming.provider.url" : "t3://host.name.mustbe.same.as.configured.on.server.side:port_number",
"java.naming.security.principal" : "wlsadmin",
"java.naming.security.credentials": "password"
]
}
//
// listener
//
jmsListenerConnectionFactory(org.springframework.jndi.JndiObjectFactoryBean) {
jndiTemplate = ref(jndiTemplate)
jndiName = "jms.checkonserver.QueueConnectionFactory"
}
jmsListenerDestinationResolver(org.springframework.jms.support.destination.JndiDestinationResolver) {
jndiTemplate = ref(jndiTemplate)
cache = false
}
userListenerCredentialsConnectionFactory(org.springframework.jms.connection.UserCredentialsConnectionFactoryAdapter){
targetConnectionFactory = ref(jmsListenerConnectionFactory)
}
standardListenerJmsTemplate(org.springframework.jms.core.JmsTemplate) {
connectionFactory = ref(userListenerCredentialsConnectionFactory)
destinationResolver = ref(jmsListenerDestinationResolver)
}
jmsListenerMessageListener(org.springframework.jms.listener.adapter.MessageListenerAdapter, ref("myListenerService")) {
defaultListenerMethod = "onMessage"
}
standardListenerJmsListenerContainer(org.springframework.jms.listener.DefaultMessageListenerContainer) {
connectionFactory = ref(jmsListenerConnectionFactory)
destinationResolver = ref(jmsListenerDestinationResolver)
messageListener = jmsListenerMessageListener
destinationName = "jms.checkonserver.MessagesQueue"
}
in services/myListenerService.groovy:
package app
class MyListenerService {
static transactional = false
static scope = "prototype"
def onMessage(msg) {
log.info "JMS msg received."
try {
String txtmsg = new String(msg as String)
log.info txtmsg
} catch (e) {
log.error e
}
}
}
Setting up JMS sender :
in conf/spring/resources.groovy:
jmsSenderConnectionFactory( org.springframework.jndi.JndiObjectFactoryBean) {
jndiTemplate = ref(jndiTemplate)
jndiName = "jms.checkonseerver.QueueConnectionFactory"
}
jmsSenderDestinationResolver(org.springframework.jms.support.destination.JndiDestinationResolver) {
jndiTemplate = ref(jndiTemplate)
cache = false
}
userSenderCredentialsConnectionFactory(org.springframework.jms.connection.UserCredentialsConnectionFactoryAdapter){
targetConnectionFactory = ref(jmsSenderConnectionFactory)
}
standardSenderJmsTemplate(org.springframework.jms.core.JmsTemplate) {
connectionFactory = ref(userSenderCredentialsConnectionFactory) //
destinationResolver = ref(jmsSenderDestinationResolver)
}
in service/myJmsSenderService.groovy:
package app
import org.springframework.jms.core.MessageCreator
import javax.jms.JMSException
import javax.jms.Message
import javax.jms.Session
class MyJmsSenderService {
static transactional = false
static scope = "prototype"
def standardSenderJmsTemplate
def sendMessage(txt) {
MessageCreator messageCreator = new MessageCreator() {
public Message createMessage(Session session) throws
JMSException {
return session.createTextMessage(txt)
}
}
standardSenderJmsTemplate.send( "jms.checkonserver.SendingQueue", messageCreator)
log.info "JMS message send: ${txt}"
}
}