GSheets Forumula Stalls on Tie Score Number - google-sheets

Question

Background Information
I am trying to setup a 1st, 2nd and 3rd rank/scoring system on Google Sheets. The sheet is setup by row and once a week a new row is added.
1. On the left-hand side of each row there are six columns. The top of each column is a cell that contains the value identifier for that column (such as a person's name or ID#). Each week the score is entered into each column.
2. The right-hand side of each row is to identify the 1st, 2nd and 3rd place winners. This area also contains six columns with the headers 1st, 2nd, 3rd. I'm trying to set it up so that each week when the new numbers are added to the next row, the relevant score is shown and the cell next to it shows the name/ID associated with that week's score. Then repeat for 2nd and 3rd.
Problem
Everything works perfectly; unless there is a tie. In that situation the information is duplicated because it stalls on the first match. I have attempted various things, including using "RANK()" and a helper column to eliminate duplicate scores, but as of yet this has me stumped. How can this be solved?
To illustrate what I am trying to do, I have an editable example sheet here:
https://docs.google.com/spreadsheets/d/1bmt77kQOtCu8OybNrWH48XKjBKD_HEZ_B6TqweZKEAI/edit?usp=sharing

Answer 1

use in J6:
=ARRAYFORMULA(ARRAY_CONSTRAIN(SORTN(SORT(SPLIT(
FLATTEN(D6:I*1&"×"&D5:I5&"×"&ROW(D6:D)), "×"),
3, 1, 1, 0), 9^9, 2, 3, 1), COUNTA(B6:B), 2))
in L6:
=ARRAYFORMULA(ARRAY_CONSTRAIN(SORTN(QUERY(QUERY(SORT(SPLIT(
FLATTEN(D6:I*1&"×"&D5:I5&"×"&ROW(D6:D)), "×"), 3, 1, 1, 0), "offset 1", ),
"skipping "&COUNTA(D5:I5), ), 9^9, 2, 3, 1), COUNTA(B6:B), 2))
in N6:
=ARRAYFORMULA(ARRAY_CONSTRAIN(SORTN(QUERY(QUERY(SORT(SPLIT(
FLATTEN(D6:I*1&"×"&D5:I5&"×"&ROW(D6:D)), "×"), 3, 1, 1, 0), "offset 2", ),
"skipping "&COUNTA(D5:I5), ), 9^9, 2, 3, 1), COUNTA(B6:B), 2))