Array of value using array formula - google-sheets

Question

I wanna return an array of value from multiple conditions, using an array formula.
I manage to make a working formula but without array formula, witch is annoying because of filling conflicts in the worksheet.
Here is the sheet
Note : current solution developped from this initial thread

Answer 1

TL;DR
Use this formula:
=ARRAYFORMULA(TRANSPOSE(SPLIT(TRANSPOSE(IF((F$1:$1&F$2:$2&F$3:$3&F$4:$4)<>"";IFERROR(REPT(";";IFERROR(VLOOKUP(F$4:$4;{$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)};2;FALSE);-1)+IFERROR(VLOOKUP(F$4:$4;{$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)};2;FALSE);-1)+IFERROR(VLOOKUP(F$4:$4;{$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)};2;FALSE);-1)+2);"#Batch? ")&IFERROR(VLOOKUP(F$1:$1&"-----"&F$2:$2;{ARRAYFORMULA(IF(LEN(Fprod!$H$2:$H);Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G;))\Fprod!$H$2:$H};2;FALSE);"#Species/supplier?");";"));";";TRUE;FALSE)))
I'll try to explain my thought process so you are able to make changes or make similar formulas in the future and for reference for other people.
Basic explanation
I've noticed a few things that will help us make a formula for this problem:
In the Fprod sheet you have the list of suppliers and species with the weeks.
There is only a single list for each batch.
Your locale doesn't allow the usage of commas in the formulas. \ must be used instead
The basic idea of the formula is to get a string defining the columns. It's basically the values on Fprod with a padding of semicolons to vertically move it. After that we want to convert it into columns (similar to how it was used in the other question). For example, if the CNC + shiitake (batch 2101) started at week 4, we want to achieve ;;;1;2;3;4;5;6 which then becomes:
2101
<empty>
<empty>
<empty>
1
2
3
4
5
6
Step 1: Getting the spec for a supplier's species
Having the supplier and the species, we want to get the weeks on Fprod (ie. having CNC + shiitake sould give us 1;2;3;4;5;6).
To do so, we'll use a VLOOKUP to get the correct list for the week. The problem is that we need to check for 2 columns. So the trick is to join both columns with some characters in the middle (eg -----) to prevent unexpected collisions. So working on the F column:
=VLOOKUP(
F$1&"-----"&F$2;
{ARRAYFORMULA(IF(LEN(Fprod!$H$2:$H); Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G;)) \ Fprod!$H$2:$H};
2;
FALSE
)
Let's unpack this, as there are already a lot of things.
Let's start with the second argument, as it's the most complex one. What it does is to make a table (2D array) where the first column is <supplier>-----<species> for each entry on Fprod, and the second column is the value we want. To make the first column we can use a ARRAYFORMULA to add both columns row by row:
=ARRAYFORMULA(Fprod!$F$2:$F & "-----" & Fprod!$G$2:$G)
The second column is simply H2:H of Fprod.
They are joined as columns. To see how this works try ={1\2} (usually it's , but because of your locale \ is required). This will generate a result similar to:
1
2
CNC-----shiitake
1;2;3;4;5;6
euro-----shiitake
1;2;3;4;5;6;7;8;9;10;11;12;13;14
euro-----pleurote
1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20;21;22
Lentin-----shiitake
1;2;3;4;5;6;7;8;9;10;11;12;13;14
Moser-----agaricus
1;2;3;4;5;6
-----
-----
As you can see we are also generating empty entries. To ignore them, we'll check that the H column of that row is not empty:
=ARRAYFORMULA(IF(LEN(Fprod!$H$2:$H); Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G;))
Now we can simply use VLOOKUP to get the value in the second column. The value we search for is in the same format as the first column. In this case we'll use the F column and generalize later. If you add this to an F column you should see 1;2;3;4;5;6 appear.
It's important to note the last argument, as the data is not sorted and setting it to true or not setting it (it's true by default) would cause problems.
Step 2: Generating the padding
To generate a padding we'll need to use some VLOOKUP to detect at what row is the value. We need 3 of them one for each column. The idea being that in the first column you have the value you need to look up (the batch) and on the second, the number of padding required. It looks like:
={$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}
$B$5:$B is simply the column B starting at row 5. ARRAYFORMULA(ROW(A5:A)-5) is a trick:
ARRAYFORMULA(ROW(Ai:Aj)) will return a count list from i to j inclusive. For example ARRAYFORMULA(ROW(A5:A6)) will return
result
5
6
In this case we need the result to have the same size as the other table so we are forced to use ARRAYFORMULA(ROW(A5:A)) to do so. Because of that the values are too big, so we need to subtract 5, giving us ARRAYFORMULA(ROW(A5:A)-5).
Join them into a single table and you have where to lookup:
=VLOOKUP(F$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE)
This is very similar to what it was done before. If you add this to F5 you'll see that it says the offset (# week minus one).
Like I pointed before wee need this for the three columns, but wee need to make sure it doesn't crash. To do that we want set a default value to -1 if not in the column. This is simple by using IFERROR.
=IFERROR(VLOOKUP(F$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1)
We cannot use MAX to join them because it cannot be used with ARRAYFORMULA because if can use ranges. Because of that we need to get creative, so I added them. This means that there is 2 -1 and the value; so adding 2 compensates it:
=IFERROR(VLOOKUP(F$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4; {$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4; {$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
2
Now we only need to use REPT to repeat ; as many times as we need:
=REPT(
";";
IFERROR(VLOOKUP(F$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4; {$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4; {$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
2
)
Step 3: Joining them
You may simply join them like you join regular strings. Note that the padding goes first
=REPT(
";";
IFERROR(VLOOKUP(F$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4; {$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4; {$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
2
)&
VLOOKUP(
F$1&"-----"&F$2;
{ARRAYFORMULA(IF(LEN(Fprod!$H$2:$H); Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G;)) \ Fprod!$H$2:$H};
2;
FALSE
)
Step 4: All the columns in one formula
Now it's a good moment to apply the formula to all columns. Basically, where you had a the column F, now we'll change it for a range on that row starting with F. For example, F4 would become F4:4.
=ARRAYFORMULA(
REPT(
";";
IFERROR(VLOOKUP(F$4:$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4:$4; {$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4:$4; {$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
2
)&
VLOOKUP(
F$1:$1&"-----"&F$2:$2;
{ARRAYFORMULA(Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G) \ Fprod!$H$2:$H};
2;
FALSE
)
)
Notice that if you have data later in the spreadsheet, it will give you an error. You can remove it or set the maximum column.
Also notice that if the column doesn't have the proper data it gives us an error. We'll fix that later.
Step 5: Split into columns
To split the representation into columns we need to use SPLIT. Split will split the values into a row. That means that we need to transpose (see Wikipedia article). So we should transpose, split, and transpose again. So let's add TRANSPOSE and SPLIT:
=ARRAYFORMULA(
TRANSPOSE(
SPLIT(
TRANSPOSE(
REPT(
";";
IFERROR(VLOOKUP(F$4:$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4:$4; {$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4:$4; {$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
2
)&
VLOOKUP(
F$1:$1&"-----"&F$2:$2;
{ARRAYFORMULA(Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G) \ Fprod!$H$2:$H};
2;
FALSE
)
);
";";
TRUE;
FALSE
)
)
)
Step 6: Handle errors
There can be 3 cases we can handle:
The species and supplier was not found on Fprod
The batch does not exist
the column is empty
For the first one, we can simply add an IFERROR to the lookup, adding a default message. For the second we can add an IFERROR wrapping REPT because it will throw an error when the number is negative (when not found). And for the last one we need to use IF with the value ";" when fails (SPLIT requires the string to not be empty).
Adding all of that we we our final result:
=ARRAYFORMULA(
TRANSPOSE(
SPLIT(
TRANSPOSE(
IF(
(F$1:$1&F$2:$2&F$3:$3&F$4:$4)<>"";
IFERROR(
REPT(
";";
IFERROR(VLOOKUP(F$4:$4; {$B$5:$B\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4:$4; {$C$5:$C\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
IFERROR(VLOOKUP(F$4:$4; {$D$5:$D\ARRAYFORMULA(ROW(A5:A)-5)}; 2; FALSE); -1) +
2
);
"#Batch? "
)&
IFERROR(
VLOOKUP(
F$1:$1&"-----"&F$2:$2;
{ARRAYFORMULA(IF(LEN(Fprod!$H$2:$H); Fprod!$F$2:$F&"-----"&Fprod!$G$2:$G;)) \ Fprod!$H$2:$H};
2;
FALSE
);
"#Species/supplier?"
);
";"
)
);
";";
TRUE;
FALSE
)
)
)
If you remove any unnecessary white-space, you get the TL;DR formula.
References
VLOOKUP (Google Docs Editors Help)
ARRAYFORMULA (Google Docs Editors Help)
SPLIT (Google Docs Editors Help)
REPT (Google Docs Editors Help)
TRANSPOSE (Google Docs Editors Help)
IF (Google Docs Editors Help)
IFERROR (Google Docs Editors Help)
ROW (Google Docs Editors Help)