Jenkins Pipeline groovy compareTo operator does not work - jenkins

Question

I had this code where I want to get the object with the oldest CreateDate in a list of json objects:
import groovy.json.JsonSlurperClassic
def result = """{
"Metadata": [
{
"Status": "Active",
"CreateDate": "2018-08-14T18:59:52Z",
},
{
"Status": "Active",
"CreateDate": "2018-05-18T16:11:45Z",
}
]
}"""
def all = new JsonSlurperClassic().parseText(result)
def oldest = all.Metadata.min { a, b ->
Date.parse("yyyy-M-d'T'H:m:s'Z'", a.CreateDate).getTime() <=>
Date.parse("yyyy-M-d'T'H:m:s'Z'", b.CreateDate).getTime() }
print "oldest=" + oldest
works fine in Jenkins Script Console. I.e: it prints the output
oldest=[Status:Active, CreateDate:2018-05-18T16:11:45Z]
But when the same code is run under Pipeline, it prints
oldest=1
Why is this?

Answer 1

This is Groovy CPS transformer bug. The difference between script console and Jenkins pipeline is that script console executes script in vanilla Groovy environment while Jenkins pipeline is executed with groovy-cps. It means that Jenkins pipeline Groovy script gets executed in the Groovy shell that uses CPS transformation - it modifies the code so it supports this continuous passing style.
According to CpsDefaultGroovyMethodsTest, groovy-cps supports collection.min {} operation, but only when the closure with a single parameter is used. I've created a test case for a closure with two parameters, like:
[3,2,5,4,5].min { int a, int b -> a <=> b }
and instead of 2 I get -1 - it looks like the value of compareTo() method is being returned and not the actual min value from the given collection.
Solution
The easiest solution to bypass this problem is to extract
def oldest = all.Metadata.min { a, b ->
Date.parse("yyyy-M-d'T'H:m:s'Z'", a.CreateDate).getTime() <=>
Date.parse("yyyy-M-d'T'H:m:s'Z'", b.CreateDate).getTime() }
to a method annotated with #NonCPS - this annotation instructs groovy-cps interpreter to skip CPS transformations and just run this method as is. Below you can find working example:
import groovy.json.JsonSlurper
node {
stage("Test") {
def result = """{
"Metadata": [
{
"Status": "Active",
"CreateDate": "2018-08-14T18:59:52Z",
},
{
"Status": "Active",
"CreateDate": "2018-05-18T16:11:45Z",
}
]
}"""
def all = new JsonSlurper().parseText(result)
def oldest = getOldest(all)
println "oldest = ${oldest}"
}
}
#NonCPS
def getOldest(all) {
return all.Metadata.min { a, b ->
Date.parse("yyyy-M-d'T'H:m:s'Z'", a.CreateDate).getTime() <=>
Date.parse("yyyy-M-d'T'H:m:s'Z'", b.CreateDate).getTime() }
}