In Google-Spreadsheet I have the below setup
B3 is set up using "Custom Formatting" : ##"°F/"##"°C"
B2 contains the formula: =ROUND(CONVERT(B3, "F", "C"))
B3=90
B2=32
What I desire to happen:
Input 90 into B3 resulting in Output B3 "90°F/32°C"; and, no visible output in B2.
I'm thinking to =CONCATENATE(B3,B2) but, I get infinite loop error.
I would then like to repeat the formula in B2 for B4, B5, B6, etc.
B3: 90
C3: =IF(B3,CONVERT(B3, "F", "C"),)
Format B3: 0.0"°F"
Format C3: 0.0"°C";"-"0.0"°C"
Copy formula to other cells using "click & drag" method
Related
In the A column, there's "A" in A1, "B" in A2, "C" in A3, "D" in A4 and "E" in A5.
In the B column, there's "F" in B1, "G" in B2, "H" in B3, "I" in B4 and "J" in B5.
In D1, I have a dropdown of A1:A5.
Like this:
I wish that E1 would show the matching B cell to the dropdown in D1.
So, for instance, if I put "A" in the dropdown, E1 would show "F", or if I put "C" in the dropdown, E1 would show "H".
Do anyone knows if this is possible in Google Sheets? If so, how?
I'm not familiar with Google Sheets or any excels-like programm, so I don't even know how to try anything, honestly.
You could use VLOOKUP. It looks in the first column of the range and returns the value in the second one:
=VLOOKUP(D1,A:B,2,0)
I have a given data columns A,B,C & E. And I tried to write a vlookup formula with autofill function in cell F1 & G1. But I don't know why F2 & G2 are blanks and move all the results offset 1 cell.
F1 formula:
={ "EventStartDate"; arrayformula(iferror(VLOOKUP(E:E,A$2:B,2,False))) }
G2 formula:
={ "BoothNo"; arrayformula(iferror(VLOOKUP(E:E,A2:C,3,False))) }
Any thoughts to rewrite the formula?
Try changing E:E to E2:E
={ "EventStartDate"; arrayformula(iferror(VLOOKUP(E2:E,A2:B,2,False))) }
and see if that works?
I want to search specific text in an entire column, the text to be searched is in another column. I am using below formula:
=ARRAYFORMULA(if(isblank(A2:A),"",IFERROR(if(REGEXMATCH(UPPER(A2:A), B2:B4),"Yes","No"),"Not Found")))
This function is comparing cell A2 with B2, A3 with B3 and so on.... I want to compare A2 with B2:B4, A3 with B2:B3...
Below is the sheet link:
https://docs.google.com/spreadsheets/d/164kxDO9aWZzr5qXjvtRlk_tiRoKU1W7Xc-Ig9VH8qzE/edit#gid=495498161
Any help on above will be greatly appreciated....
Change your formula to
=ARRAYFORMULA(if(isblank(A2:A),"",IFERROR(if(REGEXMATCH(UPPER(A2:A), TEXTJOIN("|", 1, B2:B4)),"Yes","No"),"Not Found")))
Or, in case you want an exact match:
=ARRAYFORMULA(if(isblank(A2:A),"",IFERROR(if(REGEXMATCH(UPPER(A2:A), ".*"&TEXTJOIN("|", 1, B2:B4)&".*"),"Yes","No"),"Not Found")))
Also see the duplicated sheet in the spreadsheet you shared.
See if that works?
Given two sheets that look like this:
Sheet1
a1 b1
a1 b1
Sheet2
a2 b2
a2 b2
a2 b2
How could I query for both sheets and combine all the rows together to get something line
Combined
a1 b1
a1 b1
a2 b2
a2 b2
a2 b2
I have tried the following but none of them worked
={QUERY({'Sheet1'!A1:B},"select *");QUERY({'Sheet2'!A1:B},"select *")}
=QUERY({'Sheet1'!A1:B;'Sheet2'!A1:B},"select *")
The problem with both is that I don't specify what row to end at for the two sheets. If I changed it to =QUERY({'Sheet1'!A1:B2;'Sheet2'!A1:B3},"select *"), then it would work. The problem with this is that in my actual spreadsheet, the number of rows in the sheets is changing as I am inputting more data and I would rather not have to update the query everytime.
You were close. Include the full possible ranges and add a bit to the "Select" clause:
=QUERY({Sheet1!A:B;Sheet2!A:B},"Select * Where Col1 Is Not Null")
This returns only the non-null (i.e., existing) data from each sheet.
Hello and thank you for looking at my post. I am a super noob at spreadsheets but need to automate part of a cost spreadsheet in open office calc after my assistant has repeatedly managed to forget to enter the right data. Here we go:
PART 1
Output is in cell D1.
I have a column of cells A1 to A10, if there is a number (any number) in one or more cells from A1 to A3 then I need the D1 to equal cell B1
+ 1.
If there is also a number in A4 to A6 then this supercedes the previous formula and D1 will now be B1 + 2.
Lastly if there is a number in A7 to A10 then again all previous code is superceded and D1 is now B1 + 3.
PART 2
I have cells C1 to C3. If D1 equals B1 + 1, C1 will equal D1 if greater than 3, else it will be 3. C2 and C3 must be 0 or empty.
If D1 equals B1 + 2, C2 will equal D1 if greater than 4, else it will be 4. C1 and C3 must also be 0 or empty.
If D1 equals B1 + 3, C3 will equal D1 if greater than 5, else it will be 5. C1 and C2 must also be 0 or empty.
To me this seems almost impossible, I've spent all day trying to learn IF and ELSE statements and ISNUMBER and many other approaches and I've run out of options. Any help or advice would be greatly appreciated and if I haven't been clear please ask me to clarify any point.
Find a column where you can put some other formulas, for example column E. Breaking the formula into parts will make it easier.
In E1, put =IF(E4, 3, IF(E3, 2, IF(E2, 1, 0))).
In E2, put =OR(ISNUMBER(A1),ISNUMBER(A2), ISNUMBER(A3)).
In E3, put =OR(ISNUMBER(A4),ISNUMBER(A5), ISNUMBER(A6)).
In E4, put =OR(ISNUMBER(A7),ISNUMBER(A8), ISNUMBER(A9), ISNUMBER(A10)).
Then the formula for D1 will be simply =B1 + E1. This is part 1 in the question.
For part 2, the requirement of "C2 and C3 must be 0 or empty" should not be needed, because they will be empty if D1 equals B1 + 1 anyway. So this is all that is needed:
In C1, put =IF(E1=1, IF(D1>3, D1, 3), "").
In C2, put =IF(E1=2, IF(D1>4, D1, 4), "").
In C3, put =IF(E1=3, IF(D1>5, D1, 5), "").