Match on child discriminated union - f#

Question

If I have a discriminated union with multiple values sharing a child (Apple and MoreApples both have type Apple)...
type Apples =
| GrannySmith
| Gala
type Fruit =
| Apple of Apples
| MoreApples of Apples
| Banana
let speakFruit = function
| Apple GrannySmith
| MoreApples GrannySmith -> "granny smith"
| Apple Gala
| MoreApples Gala -> "gala"
| Banana -> "banana"
Is there a way to match on the sub-union to remove duplication? - something like:
let speakFruit2 = function
| _ GrannySmith -> "granny smith"
| _ Gala -> "gala"
| Banana -> "banana"

Answer 1

I don't think there is a nice way to do this with single pattern, but you can define an active pattern that will give you an alternative perspective of the data where the two kinds of apples are merged:
let (|AnyApple|Banana|) = function
| Apple a | MoreApples a -> AnyApple a
| Banana -> Banana
This hides the standard Banana definition - you should probably use another name to avoid confusion, but the rest stays the same. Now you can pattern match using AnyApple:
let speakFruit = function
| AnyApple GrannySmith -> "granny smith"
| AnyApple Gala -> "gala"
| Banana -> "banana"

Answer 2

How about this?
let speakFruit = function
| Apple x | MoreApples x ->
match x with
| GrannySmith -> "Granny Smith"
| Gala -> "gala"
| Banana -> "banana"

Answer 3

Partial Active Pattern could also be a solution
let (|IsKind|_|) kind z =
match z with
| Apple x | MoreApples x -> if (kind = x) then Some true else None
| _ -> None
let speakFruit x =
match x with
| IsKind GrannySmith z -> "Granny Smith"
| IsKind Gala z -> "Gala"
| Banana -> "banana"
| _ -> "something else"
But to be honest - I agree with Fyodor above. You probably should rethink your types.