Result of differntiation evaluates numerically in plotting but not in standalone evaluation - maxima

Question

The following is my script:
binom_df(s, N, p):= ( N! / ( s! * (N-s)! ) ) * ( p^s ) * ( 1 - p) ^ ( N-s );
ddn_binom(s, N, p):= diff( binom_df(s, N, p), s);
ddn_binom(s, N, p);
wxplot2d(
[ binom_df( s, 100, 1/2 ), ddn_binom( s, 100, 1/2 ) ],
[s, 30, 70],
[ box, false ],
[ legend, "N=100, p= 1/2",
"diff( binom_df( s, N, p ) )"
],
[ xlabel, "s"]
);
for s: 1 thru 10 step 1 do (
display(s),
pr_val: ev( ( ddn_binom( s1, N1, p1 ) ), s1=s, N1=100, p1=0.5 ),
display(pr_val)
);
ddn_binom( 10, 100, 1/10 );
The call to ddn_binom works in wxplot2d; I get the graph. But the call to ddn_binom in the 'for' loop fails with the message:
diff: second argument must be a variable; found 1
which is the reason I have the last line with constant arguments
but it too fails with the message:
diff: second argument must be a variable; found 10
I am not conversant with the basic principles of how Maxima works.
If you can help me, I would appreciate it.
Thanks.
BD

Answer 1

(%i1) binom_df(s, N, p):= ( N! / ( s! * (N-s)! ) ) * ( p^s ) * ( 1 - p) ^ ( N-s ) $
(%i2) ddn_binom1(s, N, p):= diff(binom_df(s, N, p), s) $
In (%i2) the function body is not evaluated. It is
evaluated every time the function ddn_binom1 is called with the
formal argument s assigned to an actual argument. diff fails if s is a number.
You can use define if you want the body evaluated
(%i3) define(ddn_binom2(s, N, p), diff(binom_df(s, N, p), s)) $
fundef returns the function definitions:
(%i4) display2d: false $
(%i5) fundef(ddn_binom1);
(%o5) ddn_binom1(s,N,p):=diff(binom_df(s,N,p),s)
(%i6) fundef(ddn_binom2);
(%o6) ddn_binom2(s,N,p):=(-(N!*(1-p)^(N-s)*p^s*psi[0](s+1))/((N-s)!*s!))
+(N!*(1-p)^(N-s)*p^s*psi[0]((-s)+N+1))/((N-s)!*s!)
-(N!*log(1-p)*(1-p)^(N-s)*p^s)/((N-s)!*s!)
+(N!*(1-p)^(N-s)*p^s*log(p))/((N-s)!*s!)
Links to the documentation: operator :=, define, fundef

Answer 2

Don't use the variable s in your loop, because it's used in function.
You can first get a function and then evaulate:
for t: 1 thru 10 step 1 do (
display(t),
pr_val: ddn_binom( s1, 100, 0.5 ),
pr_val:ev(pr_val,s1=t),
display(pr_val)
);
You can also use subst:
for t: 1 thru 10 step 1 do (
display(t),
pr_val: subst(t,s1,ddn_binom( s1, 100, 0.5 )),
display(pr_val)
);