Indy Dynamic Create Server Client connecting error 10061 - delphi

Question

I am having trouble dynamically creating some INDY communication. I have not used Indy before and I can't get the server set up right. I get the error 10061. I have added a rule to the fire wall to allow this application and the port. It works if I use TServerSocket and TClientSocket but I need to use Indy.
This code does not work
procedure TForm3.Button3Click(Sender: TObject);
var
temp : TIdSocketHandles;
begin
fIdTCPServer1 := TIdTCPServer.Create(nil);
fIdTCPClient1 := TIdTCPClient.Create(nil);
temp := TIdSocketHandles.Create(fIdTCPServer1);
temp.Add.IP := 'xxx.xx.xxx.xx';//'localhost'; //gave error when tryingn to use local host
temp.Add.Port := 20200;
fIdTCPServer1.Bindings := temp;
fIdTCPServer1.OnExecute := IdTCPServer1Execute;
fIdTCPServer1.StartListening();
fIdTCPClient1.Port := 20200;
fIdTCPClient1.Host := 'xxx.xx.xxx.xx';//'localhost';
fIdTCPClient1.Connect; //error 10061 here
fIdTCPClient1.IOHandler.WriteLn('Some message');
end;
procedure TForm3.IdTCPServer1Execute(AContext: TIdContext);
var
inStr : String;
begin
inStr := AContext.Connection.IOHandler.ReadLn;
ShowMessage('Server received : ' + inStr);
end;
This code works
procedure TForm3.Button1Click(Sender: TObject);
begin
serverSocket1 := TServerSocket.Create(nil);
clientSocket1 := TClientSocket.Create(nil);
serverSocket1.Port := 20200;
serverSocket1.OnClientRead := ServerSocket1ClientRead;
serverSocket1.Active := True;
clientSocket1.Port := 20200;
clientSocket1.Host := 'localhost';
clientSocket1.Active := True;
clientSocket1.Socket.SendText('Some message');
end;
procedure TForm3.ServerSocket1ClientRead(Sender: TObject; Socket: TCustomWinSocket);
var
inStr : String;
begin
inStr := Socket.ReceiveText();
ShowMessage('Server received : ' + inStr);
end;

Answer 1

You need to set both IP address and port on each binding.
// Here you're adding a binding and setting only the IP address
temp.Add.IP := 'xxx.xx.xxx.xx';
// Here you're adding another binding and setting only the port
temp.Add.Port := 20200;
Here's an easy way to do it properly:
with fIdTCPServer1.Bindings.Add do
begin
IP := '127.0.0.1'; // Use IP address, not host name. Localhost = 127.0.0.1
Port := 20200;
end;
Here's another, more verbose, way to do it (add IdSocketHandle to your uses clause):
var
socketHandle: TIdSocketHandle;
begin
socketHandle := fIdTCPServer1.Bindings.Add;
socketHandle.IP := '127.0.0.1';
socketHandle.Port := 20200;
end;
Also, to start it up, you just need to set Active to true like this:
fIdTCPServer1.Active := True;

Answer 2

There are a few problems with your code.
you are misusing the TIdTCPServer.Bindings, and you are not activating the server correctly.
you are calling ShowMessage() in the OnExecute event, but TIdTCPServer is multithreaded component (each connected client runs in its own thread) and ShowMessage() is not thread-safe.
you have some potential memory leaks in your code.
Try this instead:
procedure TForm3.Button3Click(Sender: TObject);
var
temp : TIdSocketHandle;
begin
if fIdTCPServer1 = nil then
begin
fIdTCPServer1 := TIdTCPServer.Create(Self);
temp := fIdTCPServer1.Bindings.Add;
temp.IP := 'xxx.xx.xxx.xx';//'localhost'; //gave error when tryingn to use local host
temp.Port := 20200;
fIdTCPServer1.OnExecute := IdTCPServer1Execute;
fIdTCPServer1.Active := True;
end;
if fIdTCPClient1 = nil then
begin
fIdTCPClient1 := TIdTCPClient.Create(Self);
fIdTCPClient1.Port := 20200;
fIdTCPClient1.Host := 'xxx.xx.xxx.xx';//'localhost';
end;
fIdTCPClient1.Connect;
fIdTCPClient1.IOHandler.WriteLn('Some message');
end;
procedure TForm3.IdTCPServer1Execute(AContext: TIdContext);
var
inStr : String;
begin
inStr := AContext.Connection.IOHandler.ReadLn;
Windows.MessageBox(0, PChar(inStr), PChar('Server received'), MB_OK);
end;