Dynamic DBGrid Cell coloring - delphi

Question

I'm using Delphi XE-2 and DBGrid from Jedi component group (TJvDBGrid). Now, I found it to be very easy to define cell color when values are known, for example:
OnGetCellParams event:
if DBGrid.Field.AsInteger = 0
then Background := clYellow;
but in my case, user can define what value will have what color, that is stored on separate table. And my question, is there a way to color cell by looking up if cell value has a color assign to it?
I would appreciate any help or guidance in the matter, thank you.

Answer 1

The easiest way would probably be to use the form's OnCreate to populate an array, and then access that in the OnGetCellParams event. The array should contain as many items as there are possible values, plus a default value for array index 0 in case a color hasn't been assigned. (Untested, off-the-cuff code follows!)
type
TForm1 = class(TForm)
...
procedure FormCreate(Sender: TObject);
private
FColors: array of TColor;
end;
implementation
procedure TForm1.FormCreate(Sender: TObject);
var
NumRows, i: Integer;
begin
// One row for each possible value for the integer column you're
// trying to color the cell for (eg., if the table can hold a value
// from 0-10, you need the same # of items in the array (array[0..10])
NumRows := NumberOfPossibleValues;
SetLength(FColors, NumberOfPossibleValues);
// Pre-fill the array with the default clWindow color,
// in case a custom color isn't assigned to a value
// (for instance, the user doesn't set a color for a value
// of 7).
for i := 0 to High(FColors) do
FColors[i] := clWindow;
// Assumes your color values are in a database called FieldColors,
// in a datamodule called dmAppData, and that there's a
// column named ColValue indicating the `Field.AsInteger`
// value and the corresponding TColor stored as an integer.
dmAppData.FieldColors.First;
while not dmAppData.FieldColors.Eof do
begin
i := dmAppData.FieldColors.FieldByName('ColValue').AsInteger;
// Might want to put a check here to make sure the value isn't
// more than the number of items in the array!!!
FColors[i] := TColor(dmAppData.FieldColors.FieldByName('Color').AsInteger);
dmAppData.FieldColors.Next;
end;
end;
In your OnGetCellParams event:
Background := FColors[DBGrid.Field.AsInteger];
You might want to use a local variable in the OnGetCellParams to make sure you stay within the array bounds:
Background := clWindow;
i := DBGrid.Field.AsInteger;
if (i > 0) and (i < Length(FColors)) then
Background := FColors[i];
The much slower way would be to do a Locate in the OnGetCellParams event for every single row:
In OnGetCellParams:
Background := clWindow;
if dmAppData.FieldColors.Locate('ColValue', DBGrid.Field.AsInteger, []) then
Background := TColor(dmAppData.FieldColors.FieldByName('Color').AsInteger);