I made a Google Sheets Dictionary for my ESL students. My issue is when the sheet is pulling multiple definitions. I would like it to only pull the first/top definition from the site. I know there is a way to fix this but can't seem to figure it out.
=IFERROR(INDEX(SPLIT(CONCATENATE(IMPORTXML("https://www.learnersdictionary.com/definition/"&A4,"//span[#class='def_text']")),":",FALSE,TRUE),1,1))
try:
=IMPORTXML("https://www.learnersdictionary.com/definition/"&A4,
"//ul[#class='o_list verdana_font']")
update:
=IMPORTXML("https://www.learnersdictionary.com/definition/"&A4,
"//span[#class='def_text']")
or if you want just first one try:
=INDEX(IMPORTXML("https://www.learnersdictionary.com/definition/"&A4,
"//span[#class='def_text']"), 1, 1)
Related
I have an issue and trying to resolve it. Basically what I need to do is to compare two separate columns and see if there are some duplicates, then create separate column that will show this particular data.
Please note that this formula will need to validate different sort of symbols. I attached temple how it supposed to look like.
Since you tagged both Google sheets and Excel I'll reply for an Excel solution. Note that Google sheets and Excel aren't the same:
=FILTER(A2:A6,ISNUMBER(XMATCH(A2:A6,B2:B6)))
I have a spreadsheet that will not auto fill my array formula. Can someone please explain what I might be doing wrong on this? Example Spreadsheet (Editable)
Essentially, I'm looking through a messy tag field trying to pull out the important tag I need displayed in a separate cell. I want this done automatically so I don't have to keep pulling down my formula every morning to update the ticket sales pivot report.
A1: fe220608-dcba-12p,mg220606-dcba,reg_confirm_sms_test,confirmation_sms_mc-guidebook,mailed_v2-guidebook,preview_reminder_call_1st_attempt,phase-preview-attendee,phase-preview-buyer,product_path_quickstart,product_workshop_registration,pb,me220624-dcba,pb_mg220606-dcba,pp_2023_pre_sale,pp-2023_guest-ticket_platinum,**pp-2023_ticket_platinum**,branding_package,branding_ob_form_finished,2022_webinar_test1_group,unsubscribed_mfcp-investor-related
(I want to pull out that Platinum tag, and put it in a separate column)
Formula: =ArrayFormula(IFERROR(INDEX({"pp-2023_ticket_general-seating","pp-2023_ticket_general-admission","pp-2023_ticket_silver","pp-2023_ticket_gold","pp-2023_ticket_platinum"},MATCH(TRUE,ISNUMBER(SEARCH({"pp-2023_ticket_general-seating","pp-2023_ticket_general-admission","pp-2023_ticket_silver","pp-2023_ticket_gold","pp-2023_ticket_platinum"},A2)),0)),""))
Expected Result:
**pp-2023_ticket_platinum**
Please let me know if there is an easier way to automate this.
use:
=ARRAYFORMULA(BYROW(A2:A, LAMBDA(x, IFERROR(INDEX({
"pp-2023_ticket_general-seating","pp-2023_ticket_general-admission",
"pp-2023_ticket_silver","pp-2023_ticket_gold","pp-2023_ticket_platinum"},
MATCH(TRUE, ISNUMBER(SEARCH({
"pp-2023_ticket_general-seating","pp-2023_ticket_general-admission",
"pp-2023_ticket_silver","pp-2023_ticket_gold","pp-2023_ticket_platinum"}, x)), ))))))
I have a IMPORTHTML formula which imports a certain table from a website - but, of course, it doesn't import the images in that table too.
I was wondering how I might be able to do this.
Using vlookup, I have been able to find where the image is and everything, but I have tried using IMAGE() in a number of different places and it will never pull over the data. Really not sure how to do it.
Ideally, I would like to modify the IMPORTHTML formula in A1 to allow it to include images as well, but if I need to put it in D2 like I previously have been, then that's completely ok.
Formulas used in the images:
=IMPORTHTML("https://boards.habbousdf.com/showthread.php?tid=155","table",9)
=VLOOKUP(A2,IMPORTHTML("https://boards.habbousdf.com/showthread.php?tid=155","table",9),3,FALSE)
I was able to achieve this using the formula below
ArrayFormula(image(query(iferror(regexextract(lambda(x,filter(x,scan(,x,lambda(a,c,a+regexmatch(c,"table")))=*{table ID}*))(query(to_text(flatten(importdata("*{URL}*"))),"where Col1<>''",)),"src=.(.*\.png)")),"where Col1<>''",)))
here is a link to my google sheet for reference: [https://docs.google.com/spreadsheets/d/1tUlqB2tsH4xEsxYiMv1CiUIY3hhLGpM-1G8eWOyZPWk/edit?usp=sharing]
What I am trying to do is in the "Clients" sheet there is the column "Orders". Here I want a count of all the times that "Client ID" has been used across all the other pages. Any tips on what formula to use? Thanks
I would use:
={"Orders";ArrayFormula(IF(A2:A="","",COUNTIF({Jun!B:B;July!B:B;August!B:B;Sept!B:B}, A2:A)))}
from what i saw you only needed to add the ARRAYFORMULA to your formula, it should end up like this: =ArrayFormula(COUNTIF({Jun!B:B;July!B:B;August!B:B;Sept!B:B},A2)).
But, even after adding it, to me at least, the results didn't change. Could you verify and make sure there's a problem with the results the SUMIFS is giving you?
If you find anything that's broken I'll try and help.
I have a VLOOKUP formula to lookup from a different sheet as below:
=ARRAYFORMULA(IFERROR(VLOOKUP(B2:B6,Sheet3!A2:C,2,0)))
I would now like to expand the data on Sheet 3 but would like the next batch of data to be in range E2:G. Is it possible to have a VLOOKUP across 2 different ranges like this?
I've done lots of google searching without any joy tonight so thought I'd ask the question on here to make sure I'm not trying the impossible.
try:
=ARRAYFORMULA(IFNA(VLOOKUP(B2:B6, {Sheet3!A2:C; Sheet3!E2:G}, 2, 0)))